reset
load "gen-random.inc"
unset key

set title "How to plot a kernel density estimate for this 2D dataset?"
plot $random using 1:2

pause -1 "Press Return to continue - the plot may take some time to appear"

set view map
set palette defined (0 'white', 1 'red')
set dgrid3d 50,50 gauss kdensity
set title "set dgrid3d 50,50 gauss kdensity"

splot $random using 1:2:(1) with pm3d

pause -1 "Press Return to continue - the plot may take some time to appear"

set dgrid3d 50,50 gauss kdensity 0.1
set title "set dgrid3d 50,50 gauss kdensity 0.1"

replot

pause -1 "Hit return to continue"
reset
